iankelling.org Git - spray/blob - spray.el

   1 ;;; spray.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 Ian Kelling <ian@iankelling.org>
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation, either version 3 of the License, or
   8 ;; (at your option) any later version.
   9
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;; GNU General Public License for more details.
  14
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;; Maintainer: Ian Kelling <ian@iankelling.org>
  19 ;; Author: Ian Kelling <ian@iankelling.org>
  20 ;; Author: zk_phi
  21 ;; Created: 18 Jun 2014
  22 ;; Version: 0.0.2
  23 ;; URL: https://github.com/ian-kelling/spray
  24 ;; Mailing list: https://lists.iankelling.org/listinfo/spray
  25 ;; Keywords: convenience
  26
  27 ;;; Commentary:
  28
  29 ;; For speed reading, or just more enjoyable reading. Narrows the buffer to show
  30 ;; one word at a time. Adjust speed / pause as needed.
  31 ;;
  32 ;; Download from Melpa or put this script into a "load-path"ed directory, and
  33 ;; load it in your init file:
  34
  35 ;;   (require 'spray)
  36
  37 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  38 ;; also be useful.
  39
  40 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  41
  42 ;; In spray-mode buffers, following commands are available.
  43
  44 ;; - =spray-start/stop= (SPC) ::
  45 ;; pause or resume spraying
  46
  47 ;; - =spray-backward-word= (h, <left>) ::
  48 ;; pause and back to the last word
  49
  50 ;; - =spray-forward-word= (l, <right>) ::
  51 ;; inverse of =spray-backward-word=
  52
  53 ;; - =spray-faster= (f) ::
  54 ;; increases speed
  55
  56 ;; - =spray-slower= (s) ::
  57 ;; decreases speed
  58
  59 ;; - =spray-quit= (q, <return>) ::
  60 ;; quit =spray-mode=
  61
  62 ;; You may customize spray by modifying following items:
  63
  64 ;; - [Variable] spray-wpm
  65 ;; - [Variable] spray-height
  66 ;; - [Variable] spray-margin-top
  67 ;; - [Variable] spray-margin-left
  68 ;; - [Variable] spray-ramp
  69 ;; - [Keymap] spray-mode-map
  70 ;; - [Face] spray-base-face
  71 ;; - [Face] spray-accent-face
  72
  73 ;; Readme.org from the package repository has some additional information:
  74 ;; A gif screencast.
  75 ;; Algorithm specification.
  76 ;; Comparison with similar projects.
  77
  78 ;;; Known bugs:
  79
  80 ;; repeated words are indistinguishable, for example
  81 ;; "going, going, gone" reads like going, gone, with a slight delay.
  82 ;;
  83 ;; sentences (like this) should trigger a pause for ( and )
  84
  85 ;;; Change Log:
  86
  87 ;; 0.0.0 test release
  88 ;; 0.0.1 add spray-set-margins
  89 ;; 0.0.2 margin options, speed control, better quit
  90
  91 ;;; Code:
  92
  93 (require 'face-remap)
  94
  95 ;; * customizable vars
  96
  97 (defcustom spray-wpm 400
  98   "Words per minute"
  99   :group 'spray
 100   :type 'integer)
 101
 102 (defcustom spray-save-point nil
 103   "Set to true and then exiting spray mode will restore the point"
 104   :group 'spray
 105   :type 'boolean)
 106
 107
 108 (defcustom spray-height 400
 109   "Height of characters"
 110   :group 'spray
 111   :type 'integer)
 112
 113 (defcustom spray-margin-top 1
 114   "Character margin at top of buffer. Characters are as big as
 115   spray text characters."
 116   :group 'spray
 117   :type 'integer)
 118
 119 (defcustom spray-margin-left 1
 120   "Character margin at left of buffer. Characters are as big as
 121   spray text characters."
 122   :group 'spray
 123   :type 'integer)
 124
 125 (defcustom spray-ramp 2
 126   "Initial words before ramping up to full speed. Pauses for
 127 this multiple of wpm on the first word,
 128 decreasing by one for each subsequent word."
 129   :group 'spray
 130   :type 'integer)
 131
 132 (defcustom spray-unsupported-minor-modes
 133   '(buffer-face-mode smartparens-mode highlight-symbol-mode
 134                      column-number-mode)
 135   "Minor modes to toggle off when in spray mode."
 136   :group 'spray
 137   :type '(list symbol))
 138
 139
 140 ;; * faces
 141
 142 (defface spray-base-face
 143   '((t (:inherit default)))
 144   "Face for non-accent characters."
 145   :group 'spray)
 146
 147 (defface spray-accent-face
 148   '((t (:foreground "red" :inherit spray-base-face)))
 149   "Face for accent character."
 150   :group 'spray)
 151
 152
 153 ;; keymap
 154
 155 (defvar spray-mode-map
 156   (let ((km (make-sparse-keymap)))
 157     (define-key km (kbd "SPC") 'spray-start/stop)
 158     (define-key km (kbd "h") 'spray-backward-word)
 159     (define-key km (kbd "l") 'spray-forward-word)
 160     (define-key km (kbd "<left>") 'spray-backward-word)
 161     (define-key km (kbd "<right>") 'spray-forward-word)
 162     (define-key km (kbd "f") 'spray-faster)
 163     (define-key km (kbd "s") 'spray-slower)
 164     (define-key km (kbd "t") 'spray-time)
 165     (define-key km (kbd "q") 'spray-quit)
 166     (define-key km (kbd "<return>") 'spray-quit)
 167     (define-key km [remap forward-char] 'spray-forward-word)
 168     (define-key km [remap backward-char] 'spray-backward-word)
 169     (define-key km [remap forward-word] 'spray-forward-word)
 170     (define-key km [remap backward-word] 'spray-backward-word)
 171     (define-key km [remap keyboard-quit] 'spray-quit)
 172     km)
 173   "keymap for spray-mode buffers")
 174
 175
 176 ;; * internal vars
 177
 178 (defvar spray--margin-string "")
 179 (defvar spray--base-overlay nil)
 180 (defvar spray--accent-overlay nil)
 181 (defvar spray--running nil)
 182 (defvar spray--first-words 0)
 183 (defvar spray--initial-delay 0)
 184 (defvar spray--delay 0)
 185 (defvar spray--saved-cursor-type nil)
 186 (defvar spray--saved-restriction nil)
 187 (defvar spray--saved-minor-modes nil)
 188 (defvar spray--saved-point nil)
 189
 190 ;; * utility functions
 191
 192 (defun spray-set-margins ()
 193   "Setup spray--margin-string"
 194   (setq spray--margin-string
 195         (concat (make-string spray-margin-top 10) ;; 10 = ascii newline
 196                 (make-string spray-margin-left 32)))) ;; 32 = ascii space
 197
 198 ;; * the mode
 199
 200 ;;;###autoload
 201 (define-minor-mode spray-mode
 202   "spray mode"
 203   :init nil
 204   :keymap spray-mode-map
 205   (cond (spray-mode
 206          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 207                spray--accent-overlay (make-overlay 0 0)
 208                spray--saved-cursor-type cursor-type
 209                spray--saved-point (point)
 210                spray--saved-restriction (and (buffer-narrowed-p)
 211                                              (cons (point-min) (point-max))))
 212          (dolist (mode spray-unsupported-minor-modes)
 213            (when (and (boundp mode) (eval mode))
 214              (funcall mode -1)
 215              (push mode spray--saved-minor-modes)))
 216          (setq cursor-type nil)
 217          (let ((buffer-face-mode-face `(:height ,spray-height)))
 218            (buffer-face-mode 1))
 219          (overlay-put spray--base-overlay 'priority 100)
 220          (overlay-put spray--base-overlay 'face 'spray-base-face)
 221          (overlay-put spray--accent-overlay 'priority 101)
 222          (overlay-put spray--accent-overlay 'face 'spray-accent-face)
 223          (spray-start))
 224         (t
 225          (spray-stop)
 226          (delete-overlay spray--accent-overlay)
 227          (delete-overlay spray--base-overlay)
 228          (buffer-face-mode -1)
 229          (if spray--saved-restriction
 230              (narrow-to-region (car spray--saved-restriction)
 231                                (cdr spray--saved-restriction))
 232            (widen))
 233          (setq cursor-type spray--saved-cursor-type)
 234          (when (and spray-save-point spray--saved-point)
 235            (goto-char spray--saved-point))
 236          (dolist (mode spray--saved-minor-modes)
 237            (funcall mode 1))
 238          (setq spray--saved-minor-modes nil))))
 239
 240 (defun spray-quit ()
 241   "Exit spray mode."
 242   (interactive)
 243   (spray-mode -1))
 244
 245 (defun spray--word-at-point ()
 246   (skip-chars-backward "^\s\t\n—")
 247   (let* ((beg (point))
 248          (len (+ (skip-chars-forward "^\s\t\n—") (skip-chars-forward "—")))
 249          (end (point))
 250          (accent (+ beg (cl-case len
 251                           ((1) 1)
 252                           ((2 3 4 5) 2)
 253                           ((6 7 8 9) 3)
 254                           ((10 11 12 13) 4)
 255                           (t 5)))))
 256     ;; this fairly obfuscated, using magic numbers to store state
 257     ;; it would be nice to sometime patch this so it is more readable.
 258     ;; for greater than 9 length, we display for twice as long
 259     ;; for some punctuation, we display a blank
 260     (setq spray--delay (+ (if (> len 9) 1 0)
 261                           (if (looking-at "\n[\s\t\n]") 3 0)
 262                           (cl-case (char-before)
 263                             ((?. ?! ?\? ?\;) 3)
 264                             ((?, ?: ?—) 1)
 265                             (t 0))))
 266     (move-overlay spray--accent-overlay (1- accent) accent)
 267     (move-overlay spray--base-overlay beg end)
 268     (spray-set-margins)
 269     (overlay-put spray--base-overlay 'before-string
 270                  (concat spray--margin-string
 271                          (make-string (- 5 (- accent beg)) ?\s)))
 272     (narrow-to-region beg end)))
 273
 274 (defun spray--update ()
 275   (cond ((not (zerop spray--initial-delay))
 276          (setq spray--initial-delay (1- spray--initial-delay)))
 277         ((not (zerop spray--delay))
 278          (setq spray--delay (1- spray--delay)))
 279         (t
 280          (widen)
 281          (if (eobp)
 282              (spray-quit)
 283            (when (not (zerop spray--first-words))
 284              (setq spray--initial-delay spray--first-words)
 285              (setq spray--first-words (1- spray--first-words)))
 286            (skip-chars-forward "\s\t\n—")
 287            (spray--word-at-point)))))
 288
 289 ;; * interactive commands
 290
 291 (defun spray-start/stop ()
 292   "Toggle pause/unpause spray."
 293   (interactive)
 294   (or (spray-stop) (spray-start)))
 295
 296 (defun spray-stop ()
 297   "Pause spray.
 298 Returns t if spray was unpaused."
 299   (interactive)
 300   (prog1 spray--running
 301     (when spray--running
 302       (cancel-timer spray--running)
 303       (setq spray--running nil))))
 304
 305 (defun spray-start ()
 306   "Start / resume spray."
 307   (interactive)
 308   (setq spray--first-words spray-ramp)
 309   (setq spray--running
 310         (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 311
 312 (defun spray-forward-word ()
 313   (interactive)
 314   (spray-stop)
 315   (widen)
 316   (skip-chars-forward "\s\t\n—")
 317   (spray--word-at-point))
 318
 319 (defun spray-backward-word ()
 320   (interactive)
 321   (spray-stop)
 322   (widen)
 323   (skip-chars-backward "^\s\t\n—")
 324   (skip-chars-backward "\s\t\n—")
 325   (spray--word-at-point))
 326
 327 (defun spray-faster ()
 328   "Increases speed.
 329
 330 Increases the wpm (words per minute) parameter. See the variable
 331 `spray-wpm'."
 332   (interactive)
 333   (spray-inc-wpm 20))
 334
 335 (defun spray-slower ()
 336   "Decreases speed.
 337
 338 Decreases the wpm (words per minute) parameter. See the variable
 339 `spray-wpm'."
 340   (interactive)
 341   (spray-inc-wpm -20))
 342
 343 (defun spray-inc-wpm (delta)
 344   (let ((was-running spray--running))
 345     (spray-stop)
 346     (when (< 10 (+ spray-wpm delta))
 347       (setq spray-wpm (+ spray-wpm delta)))
 348     (and was-running (spray-backward-word))
 349     (message "spray wpm: %d" spray-wpm)
 350     (when was-running
 351       (spray-start))))
 352
 353 (defun spray-time ()
 354   (interactive)
 355   (widen)
 356   (let ((position (progn (skip-chars-backward "^\s\t\n—") (point))))
 357     (message
 358      "%d per cent done; ~%d minute(s) remaining"
 359      (* 100 (/ position (+ 0.0 (point-max))))
 360      (fround (/ (count-words-region position (point-max)) (+ 0.0 spray-wpm)))))
 361   (spray--word-at-point))
 362
 363 ;; * provide
 364
 365 (provide 'spray)
 366
 367 ;;; spray.el ends here