iankelling.org Git - spray/blob - spray.el

   1 ;;; spray.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 Ian Kelling <ian@iankelling.org>
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation, either version 3 of the License, or
   8 ;; (at your option) any later version.
   9
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;; GNU General Public License for more details.
  14
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;; Maintainer: Ian Kelling <ian@iankelling.org>
  19 ;; Author: Ian Kelling <ian@iankelling.org>
  20 ;; Author: zk_phi
  21 ;; Created: 18 Jun 2014
  22 ;; Version: 0.0.2
  23 ;; URL: https://github.com/ian-kelling/spray
  24 ;; Keywords: convenience
  25
  26 ;;; Commentary:
  27
  28 ;; For speed reading, or just more enjoyable reading. Narrows the buffer to show
  29 ;; one word at a time. Adjust speed / pause as needed.
  30 ;;
  31 ;; Download from Melpa or put this script into a "load-path"ed directory, and
  32 ;; load it in your init file:
  33
  34 ;;   (require 'spray)
  35
  36 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  37 ;; also be useful.
  38
  39 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  40
  41 ;; In spray-mode buffers, following commands are available.
  42
  43 ;; - =spray-start/stop= (SPC) ::
  44 ;; pause or resume spraying
  45
  46 ;; - =spray-backward-word= (h, <left>) ::
  47 ;; pause and back to the last word
  48
  49 ;; - =spray-forward-word= (l, <right>) ::
  50 ;; inverse of =spray-backward-word=
  51
  52 ;; - =spray-faster= (f) ::
  53 ;; increases speed
  54
  55 ;; - =spray-slower= (s) ::
  56 ;; decreases speed
  57
  58 ;; - =spray-quit= (q, <return>) ::
  59 ;; quit =spray-mode=
  60
  61 ;; You may customize spray by modifying following items:
  62
  63 ;; - [Variable] spray-wpm
  64 ;; - [Variable] spray-height
  65 ;; - [Variable] spray-margin-top
  66 ;; - [Variable] spray-margin-left
  67 ;; - [Variable] spray-ramp
  68 ;; - [Keymap] spray-mode-map
  69 ;; - [Face] spray-base-face
  70 ;; - [Face] spray-accent-face
  71
  72 ;; Readme.org from the package repository has some additional information:
  73 ;; A gif screencast.
  74 ;; Algorithm specification.
  75 ;; Comparison with similar projects.
  76
  77 ;;; Known bugs:
  78
  79 ;; repeated words are indistinguishable, for example
  80 ;; "going, going, gone" reads like going, gone, with a slight delay.
  81 ;;
  82 ;; sentences (like this) should trigger a pause for ( and )
  83
  84 ;;; Change Log:
  85
  86 ;; 0.0.0 test release
  87 ;; 0.0.1 add spray-set-margins
  88 ;; 0.0.2 margin options, speed control, better quit
  89
  90 ;;; Code:
  91
  92 (require 'face-remap)
  93
  94 ;; * customizable vars
  95
  96 (defcustom spray-wpm 400
  97   "Words per minute"
  98   :group 'spray
  99   :type 'integer)
 100
 101 (defcustom spray-height 400
 102   "Height of characters"
 103   :group 'spray
 104   :type 'integer)
 105
 106 (defcustom spray-margin-top 1
 107   "Character margin at top of buffer. Characters are as big as
 108   spray text characters."
 109   :group 'spray
 110   :type 'integer)
 111
 112 (defcustom spray-margin-left 1
 113   "Character margin at left of buffer. Characters are as big as
 114   spray text characters."
 115   :group 'spray
 116   :type 'integer)
 117
 118 (defcustom spray-ramp 2
 119   "Initial words before ramping up to full speed. Pauses for
 120 this multiple of wpm on the first word,
 121 decreasing by one for each subsequent word."
 122   :group 'spray
 123   :type 'integer)
 124
 125 (defcustom spray-unsupported-minor-modes
 126   '(buffer-face-mode smartparens-mode highlight-symbol-mode
 127                      column-number-mode)
 128   "Minor modes to toggle off when in spray mode."
 129   :group 'spray
 130   :type '(list symbol))
 131
 132
 133 ;; * faces
 134
 135 (defface spray-base-face
 136   '((t (:inherit default)))
 137   "Face for non-accent characters."
 138   :group 'spray)
 139
 140 (defface spray-accent-face
 141   '((t (:foreground "red" :inherit spray-base-face)))
 142   "Face for accent character."
 143   :group 'spray)
 144
 145
 146 ;; keymap
 147
 148 (defvar spray-mode-map
 149   (let ((km (make-sparse-keymap)))
 150     (define-key km (kbd "SPC") 'spray-start/stop)
 151     (define-key km (kbd "h") 'spray-backward-word)
 152     (define-key km (kbd "l") 'spray-forward-word)
 153     (define-key km (kbd "<left>") 'spray-backward-word)
 154     (define-key km (kbd "<right>") 'spray-forward-word)
 155     (define-key km (kbd "f") 'spray-faster)
 156     (define-key km (kbd "s") 'spray-slower)
 157     (define-key km (kbd "q") 'spray-quit)
 158     (define-key km (kbd "<return>") 'spray-quit)
 159     (define-key km [remap forward-char] 'spray-forward-word)
 160     (define-key km [remap backward-char] 'spray-backward-word)
 161     (define-key km [remap forward-word] 'spray-forward-word)
 162     (define-key km [remap backward-word] 'spray-backward-word)
 163     (define-key km [remap keyboard-quit] 'spray-quit)
 164     km)
 165   "keymap for spray-mode buffers")
 166
 167
 168 ;; * internal vars
 169
 170 (defvar spray--margin-string "")
 171 (defvar spray--base-overlay nil)
 172 (defvar spray--accent-overlay nil)
 173 (defvar spray--running nil)
 174 (defvar spray--first-words 0)
 175 (defvar spray--initial-delay 0)
 176 (defvar spray--delay 0)
 177 (defvar spray--saved-cursor-type nil)
 178 (defvar spray--saved-restriction nil)
 179 (defvar spray--saved-minor-modes nil)
 180
 181 ;; * utility functions
 182
 183 (defun spray-set-margins ()
 184   "Setup spray--margin-string"
 185   (setq spray--margin-string
 186         (concat (make-string spray-margin-top 10) ;; 10 = ascii newline
 187                 (make-string spray-margin-left 32)))) ;; 32 = ascii space
 188
 189 ;; * the mode
 190
 191 ;;;###autoload
 192 (define-minor-mode spray-mode
 193   "spray mode"
 194   :init nil
 195   :keymap spray-mode-map
 196   (cond (spray-mode
 197          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 198                spray--accent-overlay (make-overlay 0 0)
 199                spray--saved-cursor-type cursor-type
 200                spray--saved-restriction (and (buffer-narrowed-p)
 201                                              (cons (point-min) (point-max))))
 202          (dolist (mode spray-unsupported-minor-modes)
 203            (when (and (boundp mode) (eval mode))
 204              (funcall mode -1)
 205              (push mode spray--saved-minor-modes)))
 206          (setq cursor-type nil)
 207          (let ((buffer-face-mode-face `(:height ,spray-height)))
 208            (buffer-face-mode 1))
 209          (overlay-put spray--base-overlay 'priority 100)
 210          (overlay-put spray--base-overlay 'face 'spray-base-face)
 211          (overlay-put spray--accent-overlay 'priority 101)
 212          (overlay-put spray--accent-overlay 'face 'spray-accent-face)
 213          (spray-start))
 214         (t
 215          (spray-stop)
 216          (delete-overlay spray--accent-overlay)
 217          (delete-overlay spray--base-overlay)
 218          (buffer-face-mode -1)
 219          (if spray--saved-restriction
 220              (narrow-to-region (car spray--saved-restriction)
 221                                (cdr spray--saved-restriction))
 222            (widen))
 223          (setq cursor-type spray--saved-cursor-type)
 224          (dolist (mode spray--saved-minor-modes)
 225            (funcall mode 1))
 226          (setq spray--saved-minor-modes nil))))
 227
 228 (defun spray-quit ()
 229   "Exit spray mode."
 230   (interactive)
 231   (spray-mode -1))
 232
 233 (defun spray--word-at-point ()
 234   (skip-chars-backward "^\s\t\n—")
 235   (let* ((beg (point))
 236          (len (+ (skip-chars-forward "^\s\t\n—") (skip-chars-forward "—")))
 237          (end (point))
 238          (accent (+ beg (cl-case len
 239                        ((1) 1)
 240                        ((2 3 4 5) 2)
 241                        ((6 7 8 9) 3)
 242                        ((10 11 12 13) 4)
 243                        (t 5)))))
 244     ;; this fairly obfuscated, using magic numbers to store state
 245     ;; it would be nice to sometime patch this so it is more readable.
 246     ;; for greater than 9 length, we display for twice as long
 247     ;; for some punctuation, we display a blank
 248     (setq spray--delay (+ (if (> len 9) 1 0)
 249                           (if (looking-at "\n[\s\t\n]") 3 0)
 250                           (cl-case (char-before)
 251                             ((?. ?! ?\? ?\;) 3)
 252                             ((?, ?: ?—) 1)
 253                             (t 0))))
 254     (move-overlay spray--accent-overlay (1- accent) accent)
 255     (move-overlay spray--base-overlay beg end)
 256     (spray-set-margins)
 257     (overlay-put spray--base-overlay 'before-string
 258                  (concat spray--margin-string
 259                          (make-string (- 5 (- accent beg)) ?\s)))
 260     (narrow-to-region beg end)))
 261
 262 (defun spray--update ()
 263   (cond ((not (zerop spray--initial-delay))
 264          (setq spray--initial-delay (1- spray--initial-delay)))
 265         ((not (zerop spray--delay))
 266          (setq spray--delay (1- spray--delay))
 267          (when (= spray--delay 2)
 268            (narrow-to-region (point) (point))))
 269         (t
 270          (widen)
 271          (if (eobp)
 272              (spray-mode -1)
 273            (when (not (zerop spray--first-words))
 274              (setq spray--initial-delay spray--first-words)
 275              (setq spray--first-words (1- spray--first-words)))
 276            (skip-chars-forward "\s\t\n—")
 277            (spray--word-at-point)))))
 278
 279 ;; * interactive commands
 280
 281 (defun spray-start/stop ()
 282   "Toggle pause/unpause spray."
 283   (interactive)
 284   (or (spray-stop) (spray-start)))
 285
 286 (defun spray-stop ()
 287   "Pause spray.
 288 Returns t if spray was unpaused."
 289   (interactive)
 290   (prog1 spray--running
 291     (when spray--running
 292       (cancel-timer spray--running)
 293       (setq spray--running nil))))
 294
 295 (defun spray-start ()
 296   "Start / resume spray."
 297   (interactive)
 298   (setq spray--first-words spray-ramp)
 299   (setq spray--running
 300         (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 301
 302 (defun spray-forward-word ()
 303   (interactive)
 304   (spray-stop)
 305   (widen)
 306   (skip-chars-forward "\s\t\n—")
 307   (spray--word-at-point))
 308
 309 (defun spray-backward-word ()
 310   (interactive)
 311   (spray-stop)
 312   (widen)
 313   (skip-chars-backward "^\s\t\n—")
 314   (skip-chars-backward "\s\t\n—")
 315   (spray--word-at-point))
 316
 317 (defun spray-faster ()
 318   "Increases speed.
 319
 320 Increases the wpm (words per minute) parameter. See the variable
 321 `spray-wpm'."
 322   (interactive)
 323   (spray-inc-wpm 20))
 324
 325 (defun spray-slower ()
 326   "Decreases speed.
 327
 328 Decreases the wpm (words per minute) parameter. See the variable
 329 `spray-wpm'."
 330   (interactive)
 331   (spray-inc-wpm -20))
 332
 333 (defun spray-inc-wpm (delta)
 334   (let ((was-running spray--running))
 335     (spray-stop)
 336     (when (< 10 (+ spray-wpm delta))
 337       (setq spray-wpm (+ spray-wpm delta)))
 338     (and was-running (spray-backward-word))
 339     (message "spray wpm: %d" spray-wpm)
 340     (when was-running
 341       (spray-start))))
 342
 343 ;; * provide
 344
 345 (provide 'spray)
 346
 347 ;;; spray.el ends here