iankelling.org Git - spray/blob - spray.el

   1 ;;; spray.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 zk_phi
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation; either version 2 of the License, or
   8 ;; (at your option) any later version.
   9 ;;
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 ;; GNU General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program; if not, write to the Free Software
  17 ;; Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;; Author: zk_phi
  20 ;; URL: http://hins11.yu-yake.com/
  21 ;; Author: Ian Kelling <ian@iankelling.org>
  22 ;; Version: 0.0.2
  23
  24 ;;; Commentary:
  25
  26 ;; Put this script into a "load-path"ed directory, and load it in your
  27 ;; init file.
  28 ;;
  29 ;;   (require 'spray)
  30 ;;
  31 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  32 ;; also be useful.
  33 ;;
  34 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  35 ;;
  36 ;; For more informations, see Readme.org.
  37
  38 ;; Known bugs.
  39 ;; repeated words are indistinguishable, for example
  40 ;; "going, going, gone" reads like going, gone, with a slight delay.
  41 ;;
  42 ;; sentences (like this) should trigger a pause for ( and )
  43
  44 ;;; Change Log:
  45 ;; 0.0.0 test release
  46 ;; 0.0.1 add spray-set-margins
  47 ;; 0.0.2 margin options, speed control, better quit
  48
  49 ;;; Code:
  50
  51 (require 'face-remap)
  52
  53 ;; * customizable vars
  54
  55 (defvar spray-wpm 400
  56   "words/min")
  57
  58 (defvar spray-height 400
  59   "height of characters")
  60
  61 (defvar spray-margin-top 1
  62   "character margin at top of buffer. Characters are as big as
  63   spray text characters.")
  64
  65 (defvar spray-margin-left 1
  66   "character margin at left of buffer. Characters are as big as
  67   spray text characters.")
  68
  69 (defvar spray-ramp 2
  70   "Ramp up to full speed. Pause for this multiple of wpm on the first word,
  71 decreasing by one for each subsequent word.")
  72
  73 (defvar spray-mode-map
  74   (let ((km (make-sparse-keymap)))
  75     (define-key km (kbd "SPC") 'spray-start/stop)
  76     (define-key km (kbd "h") 'spray-backward-word)
  77     (define-key km (kbd "l") 'spray-forward-word)
  78     (define-key km (kbd "<left>") 'spray-backward-word)
  79     (define-key km (kbd "<right>") 'spray-forward-word)
  80     (define-key km (kbd "f") 'spray-faster)
  81     (define-key km (kbd "s") 'spray-slower)
  82     (define-key km (kbd "q") 'spray-quit)
  83     (define-key km (kbd "<return>") 'spray-quit)
  84     (define-key km [remap forward-char] 'spray-forward-word)
  85     (define-key km [remap backward-char] 'spray-backward-word)
  86     (define-key km [remap forward-word] 'spray-forward-word)
  87     (define-key km [remap backward-word] 'spray-backward-word)
  88     (define-key km [remap keyboard-quit] 'spray-quit)
  89     km)
  90   "keymap for spray-mode buffers")
  91
  92 (defvar spray-unsupported-minor-modes
  93   '(buffer-face-mode smartparens-mode highlight-symbol-mode))
  94
  95 ;; * faces
  96
  97 (make-face 'spray-base-face)
  98 (set-face-attribute 'spray-base-face nil
  99                     :inherit 'default)
 100
 101 (make-face 'spray-accent-face)
 102 (set-face-attribute 'spray-accent-face nil
 103                     :inherit 'spray-base-face
 104                     :foreground "red")
 105
 106 ;; * internal vars
 107
 108 (defvar spray--margin-string "")
 109 (defvar spray--base-overlay nil)
 110 (defvar spray--accent-overlay nil)
 111 (defvar spray--running nil)
 112 (defvar spray--first-words 0)
 113 (defvar spray--initial-delay 0)
 114 (defvar spray--delay 0)
 115 (defvar spray--saved-cursor-type nil)
 116 (defvar spray--saved-restriction nil)
 117 (defvar spray--saved-minor-modes nil)
 118
 119 ;; * utility functions
 120
 121 (defun spray-set-margins ()
 122   "Setup spray--margin-string"
 123   (setq spray--margin-string
 124         (concat (make-string spray-margin-top 10) ;; 10 = ascii newline
 125                 (make-string spray-margin-left 32)))) ;; 32 = ascii space
 126
 127 ;; * the mode
 128
 129 ;;;###autoload
 130 (define-minor-mode spray-mode
 131   "spray mode"
 132   :init nil
 133   :keymap spray-mode-map
 134   (cond (spray-mode
 135          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 136                spray--accent-overlay (make-overlay 0 0)
 137                spray--saved-cursor-type cursor-type
 138                spray--saved-restriction (and (buffer-narrowed-p)
 139                                              (cons (point-min) (point-max))))
 140          (dolist (mode spray-unsupported-minor-modes)
 141            (when (and (boundp mode) (eval mode))
 142              (funcall mode -1)
 143              (push mode spray--saved-minor-modes)))
 144          (setq cursor-type nil)
 145          (let ((buffer-face-mode-face `(:height ,spray-height)))
 146            (buffer-face-mode 1))
 147          (overlay-put spray--base-overlay 'priority 100)
 148          (overlay-put spray--base-overlay 'face 'spray-base-face)
 149          (overlay-put spray--accent-overlay 'priority 101)
 150          (overlay-put spray--accent-overlay 'face 'spray-accent-face)
 151          (spray-start))
 152         (t
 153          (spray-stop)
 154          (delete-overlay spray--accent-overlay)
 155          (delete-overlay spray--base-overlay)
 156          (buffer-face-mode -1)
 157          (if spray--saved-restriction
 158              (narrow-to-region (car spray--saved-restriction)
 159                                (cdr spray--saved-restriction))
 160            (widen))
 161          (setq cursor-type spray--saved-cursor-type)
 162          (dolist (mode spray--saved-minor-modes)
 163            (funcall mode 1))
 164          (setq spray--saved-minor-modes nil))))
 165
 166 (defun spray-quit ()
 167   "Exit spray mode."
 168   (interactive)
 169   (spray-mode -1))
 170
 171 (defun spray--word-at-point ()
 172   (skip-chars-backward "^\s\t\n—")
 173   (let* ((beg (point))
 174          (len (+ (skip-chars-forward "^\s\t\n—") (skip-chars-forward "—")))
 175          (end (point))
 176          (accent (+ beg (cl-case len
 177                        ((1) 1)
 178                        ((2 3 4 5) 2)
 179                        ((6 7 8 9) 3)
 180                        ((10 11 12 13) 4)
 181                        (t 5)))))
 182     ;; this fairly obfuscated, using magic numbers to store state
 183     ;; it would be nice to sometime patch this so it is more readable.
 184     ;; for greater than 9 length, we display for twice as long
 185     ;; for some punctuation, we display a blank
 186     (setq spray--delay (+ (if (> len 9) 1 0)
 187                           (if (looking-at "\n[\s\t\n]") 3 0)
 188                           (cl-case (char-before)
 189                             ((?. ?! ?\? ?\;) 3)
 190                             ((?, ?: ?—) 1)
 191                             (t 0))))
 192     (move-overlay spray--accent-overlay (1- accent) accent)
 193     (move-overlay spray--base-overlay beg end)
 194     (spray-set-margins)
 195     (overlay-put spray--base-overlay 'before-string
 196                  (concat spray--margin-string
 197                          (make-string (- 5 (- accent beg)) ?\s)))
 198     (narrow-to-region beg end)))
 199
 200 (defun spray--update ()
 201   (cond ((not (zerop spray--initial-delay))
 202          (setq spray--initial-delay (1- spray--initial-delay)))
 203         ((not (zerop spray--delay))
 204          (setq spray--delay (1- spray--delay))
 205          (when (= spray--delay 2)
 206            (narrow-to-region (point) (point))))
 207         (t
 208          (widen)
 209          (if (eobp)
 210              (spray-mode -1)
 211            (when (not (zerop spray--first-words))
 212              (setq spray--initial-delay spray--first-words)
 213              (setq spray--first-words (1- spray--first-words)))
 214            (skip-chars-forward "\s\t\n—")
 215            (spray--word-at-point)))))
 216
 217 ;; * interactive commands
 218
 219 (defun spray-start/stop ()
 220   "Toggle pause/unpause spray."
 221   (interactive)
 222   (or (spray-stop) (spray-start)))
 223
 224 (defun spray-stop ()
 225   "Pause spray.
 226 Returns t if spray was unpaused."
 227   (interactive)
 228   (prog1 spray--running
 229     (when spray--running
 230       (cancel-timer spray--running)
 231       (setq spray--running nil))))
 232
 233 (defun spray-start ()
 234   "Start / resume spray."
 235   (interactive)
 236   (setq spray--first-words spray-ramp)
 237   (setq spray--running
 238         (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 239
 240 (defun spray-forward-word ()
 241   (interactive)
 242   (spray-stop)
 243   (widen)
 244   (skip-chars-forward "\s\t\n—")
 245   (spray--word-at-point))
 246
 247 (defun spray-backward-word ()
 248   (interactive)
 249   (spray-stop)
 250   (widen)
 251   (skip-chars-backward "^\s\t\n—")
 252   (skip-chars-backward "\s\t\n—")
 253   (spray--word-at-point))
 254
 255 (defun spray-faster ()
 256   "Increases speed.
 257
 258 Increases the wpm (words per minute) parameter. See the variable
 259 `spray-wpm'."
 260   (interactive)
 261   (spray-inc-wpm 20))
 262
 263 (defun spray-slower ()
 264   "Decreases speed.
 265
 266 Decreases the wpm (words per minute) parameter. See the variable
 267 `spray-wpm'."
 268   (interactive)
 269   (spray-inc-wpm -20))
 270
 271 (defun spray-inc-wpm (delta)
 272   (let ((was-running spray--running))
 273     (spray-stop)
 274     (when (< 10 (+ spray-wpm delta))
 275       (setq spray-wpm (+ spray-wpm delta)))
 276     (and was-running (spray-backward-word))
 277     (message "spray wpm: %d" spray-wpm)
 278     (when was-running
 279       (spray-start))))
 280
 281 ;; * provide
 282
 283 (provide 'spray)
 284
 285 ;;; spray.el ends here