iankelling.org Git - spray/blob - spray.el

   1 ;;; cedit.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 zk_phi
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation; either version 2 of the License, or
   8 ;; (at your option) any later version.
   9 ;;
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 ;; GNU General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program; if not, write to the Free Software
  17 ;; Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;; Author: zk_phi
  20 ;; URL: http://hins11.yu-yake.com/
  21 ;; Version: 0.0.1
  22
  23 ;;; Commentary:
  24
  25 ;; Put this script into a "load-path"ed directory, and load it in your
  26 ;; init file.
  27 ;;
  28 ;;   (require 'spray)
  29 ;;
  30 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  31 ;; also be useful.
  32 ;;
  33 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  34 ;;
  35 ;; For more informations, see Readme.org.
  36
  37 ;;; Change Log:
  38 ;; 0.0.0 test release
  39 ;; 0.0.1 add spray-set-margins
  40
  41 ;;; Code:
  42
  43 (require 'face-remap)
  44
  45 ;; * customizable vars
  46
  47 (defvar spray-wpm 400 "words/min")
  48 (defvar spray-height 400 "height of characters")
  49
  50 (defvar spray-mode-map
  51   (let ((km (make-sparse-keymap)))
  52     (define-key km (kbd "SPC") 'spray-start/stop)
  53     (define-key km (kbd "h") 'spray-backward-word)
  54     (define-key km (kbd "l") 'spray-forward-word)
  55     (define-key km (kbd "<left>") 'spray-backward-word)
  56     (define-key km (kbd "<right>") 'spray-forward-word)
  57     (define-key km (kbd "f") 'spray-faster)
  58     (define-key km (kbd "s") 'spray-slower)
  59     km)
  60   "keymap for spray-mode buffers")
  61
  62 ;; * faces
  63
  64 (make-face 'spray-base-face)
  65 (set-face-attribute 'spray-base-face nil
  66                     :background (face-background 'default)
  67                     :foreground (face-foreground 'default)
  68                     :slant 'normal)
  69
  70 (make-face 'spray-orp-face)
  71 (set-face-attribute 'spray-orp-face nil
  72                     :foreground "red"
  73                     :overline (face-foreground 'default)
  74                     :underline (face-foreground 'default)
  75                     :slant 'normal)
  76
  77 ;; * internal vars
  78
  79 (defvar spray--margin-string "")
  80 (defvar spray--base-overlay nil)
  81 (defvar spray--orp-overlay nil)
  82 (defvar spray--running nil)
  83 (defvar spray--delay 0)
  84 (defvar spray--saved-cursor-type nil)
  85 (defvar spray--saved-buffer-face nil)
  86 (defvar spray--saved-restriction nil)
  87
  88 ;; * utility functions
  89
  90 (defun spray-set-margins (left above)
  91   "add margins before/above the spray text. each arguments can be
  92 an integer or a float value."
  93   (setq spray--margin-string
  94         (propertize " " 'display `((space-width ,left) (height ,(1+ above))))))
  95
  96 ;; * the mode
  97
  98 ;;;###autoload
  99 (define-minor-mode spray-mode
 100   "spray mode"
 101   :init nil
 102   :keymap spray-mode-map
 103   (cond (spray-mode
 104          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 105                spray--orp-overlay (make-overlay 0 0)
 106                spray--saved-cursor-type cursor-type
 107                spray--saved-restriction (and (buffer-narrowed-p)
 108                                              (cons (point-min) (point-max)))
 109                spray--saved-buffer-face (and (boundp 'buffer-face-mode)
 110                                              buffer-face-mode
 111                                              buffer-face-mode-face))
 112          (setq cursor-type nil)
 113          (let ((buffer-face-mode-face `(:height ,spray-height)))
 114            (buffer-face-mode 1))
 115          (overlay-put spray--base-overlay 'priority 100)
 116          (overlay-put spray--base-overlay 'face 'spray-base-face)
 117          (overlay-put spray--orp-overlay 'priority 101)
 118          (overlay-put spray--orp-overlay 'face 'spray-orp-face)
 119          (add-hook 'pre-command-hook 'spray--pre-command-handler)
 120          (spray-start/stop 1))
 121         (t
 122          (setq cursor-type spray--saved-cursor-type)
 123          (if spray--saved-restriction
 124              (narrow-to-region (car spray--saved-restriction)
 125                                (cdr spray--saved-restriction))
 126            (widen))
 127          (buffer-face-mode -1)
 128          (if spray--saved-buffer-face
 129              (let ((buffer-face-mode-face spray--saved-buffer-face))
 130                (buffer-face-mode 1)))
 131          (delete-overlay spray--base-overlay)
 132          (delete-overlay spray--orp-overlay)
 133          (remove-hook 'pre-command-hook 'spray--pre-command-handler)
 134          (spray-start/stop -1))))
 135
 136 (defun spray--pre-command-handler ()
 137   (unless (string-match "^spray-" (symbol-name this-command))
 138     (spray-mode -1)))
 139
 140 (defun spray--word-at-point ()
 141   (skip-chars-backward "^\s\t\n")
 142   (let* ((beg (point))
 143          (len (skip-chars-forward "^\s\t\n"))
 144          (end (point))
 145          (orp (+ beg (cl-case len
 146                        ((1) 1)
 147                        ((2 3 4 5) 2)
 148                        ((6 7 8 9) 3)
 149                        ((10 11 12 13) 4)
 150                        (t 5)))))
 151     (setq spray--delay (+ (if (> len 9) 1 0)
 152                           (if (looking-at "\n[\s\t\n]") 3 0)
 153                           (cl-case (char-before)
 154                             ((?. ?! ?\? ?\;) 3)
 155                             ((?, ?:) 1)
 156                             (t 0))))
 157     (move-overlay spray--orp-overlay (1- orp) orp)
 158     (move-overlay spray--base-overlay beg end)
 159     (overlay-put spray--base-overlay 'before-string
 160                  (concat spray--margin-string
 161                          (make-string (- 5 (- orp beg)) ?\s)))
 162     (narrow-to-region beg end)))
 163
 164 (defun spray--update ()
 165   (cond ((not (zerop spray--delay))
 166          (setq spray--delay (1- spray--delay))
 167          (when (= spray--delay 2)
 168            (narrow-to-region (point) (point))))
 169         (t
 170          (widen)
 171          (if (eobp)
 172              (spray-mode -1)
 173            (skip-chars-forward "\s\t\n")
 174            (spray--word-at-point)))))
 175
 176 ;; * interactive commands
 177
 178 (defun spray-start/stop (&optional switch)
 179   (interactive)
 180   (cond ((and (memql switch '(nil 1))
 181               (not spray--running))
 182          (setq spray--running
 183                (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 184         ((memql switch '(nil -1))
 185          (cancel-timer spray--running)
 186          (setq spray--running nil))
 187         (t
 188          nil)))
 189
 190 (defun spray-forward-word ()
 191   (interactive)
 192   (when spray--running (spray-start/stop -1))
 193   (widen)
 194   (skip-chars-forward "\s\t\n")
 195   (spray--word-at-point))
 196
 197 (defun spray-backward-word ()
 198   (interactive)
 199   (when spray--running (spray-start/stop -1))
 200   (widen)
 201   (skip-chars-backward "^\s\t\n")
 202   (skip-chars-backward "\s\t\n")
 203   (spray--word-at-point))
 204
 205 (defun spray-faster ()
 206   "Increases speed.
 207
 208 Increases the wpm (words per minute) parameter. See the variable
 209 `spray-wmp'."
 210   (interactive)
 211   (spray-inc-wpm 20))
 212
 213 (defun spray-slower ()
 214   "Decreases speed.
 215
 216 Decreases the wpm (words per minute) parameter. See the variable
 217 `spray-wmp'."
 218   (interactive)
 219   (spray-inc-wpm -20))
 220
 221 (defun spray-inc-wpm (delta)
 222   (let ((was-running spray--running))
 223     (spray-start/stop -1)
 224     (when (< 10 (+ spray-wpm delta))
 225       (setq spray-wpm (+ spray-wpm delta)))
 226     (spray-backward-word)
 227     (message "spray wpm: %d" spray-wpm)
 228     (when was-running
 229       (spray-start/stop 1))))
 230
 231 ;; * provide
 232
 233 (provide 'spray)
 234
 235 ;;; spray.el ends here