iankelling.org Git - spray/blob - spray.el

   1 ;;; spray.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 Ian Kelling <ian@iankelling.org>
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation; either version 2 of the License, or
   8 ;; (at your option) any later version.
   9 ;;
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 ;; GNU General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program; if not, write to the Free Software
  17 ;; Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;; Maintainer: Ian Kelling <ian@iankelling.org>
  20 ;; Author: Ian Kelling <ian@iankelling.org>
  21 ;; Author: zk_phi
  22 ;; Created: 18 Jun 2014
  23 ;; Version: 0.0.2
  24 ;; URL: https://github.com/ian-kelling/spray
  25 ;; Keywords: convenience
  26
  27 ;;; Commentary:
  28
  29 ;; For speed reading, or just more enjoyable reading. Narrows the buffer to show
  30 ;; one word at a time. Adjust speed / pause as needed.
  31 ;;
  32 ;; Download from Melpa or put this script into a "load-path"ed directory, and
  33 ;; load it in your init file:
  34
  35 ;;   (require 'spray)
  36
  37 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  38 ;; also be useful.
  39
  40 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  41
  42 ;; In spray-mode buffers, following commands are available.
  43
  44 ;; - =spray-start/stop= (SPC) ::
  45 ;; pause or resume spraying
  46
  47 ;; - =spray-backward-word= (h, <left>) ::
  48 ;; pause and back to the last word
  49
  50 ;; - =spray-forward-word= (l, <right>) ::
  51 ;; inverse of =spray-backward-word=
  52
  53 ;; - =spray-faster= (f) ::
  54 ;; increases speed
  55
  56 ;; - =spray-slower= (s) ::
  57 ;; decreases speed
  58
  59 ;; - =spray-quit= (q, <return>) ::
  60 ;; quit =spray-mode=
  61
  62 ;; You may customize spray by modifying following items:
  63
  64 ;; - [Variable] spray-wpm
  65 ;; - [Variable] spray-height
  66 ;; - [Variable] spray-margin-top
  67 ;; - [Variable] spray-margin-left
  68 ;; - [Variable] spray-ramp
  69 ;; - [Keymap] spray-mode-map
  70 ;; - [Face] spray-base-face
  71 ;; - [Face] spray-accent-face
  72
  73 ;; Readme.org from the package repository has some additional information:
  74 ;; A gif screencast.
  75 ;; Algorithm specification.
  76 ;; Comparison with similar projects.
  77
  78 ;;; Known bugs:
  79
  80 ;; repeated words are indistinguishable, for example
  81 ;; "going, going, gone" reads like going, gone, with a slight delay.
  82 ;;
  83 ;; sentences (like this) should trigger a pause for ( and )
  84
  85 ;;; Change Log:
  86
  87 ;; 0.0.0 test release
  88 ;; 0.0.1 add spray-set-margins
  89 ;; 0.0.2 margin options, speed control, better quit
  90
  91 ;;; Code:
  92
  93 (require 'face-remap)
  94
  95 ;; * customizable vars
  96
  97 (defcustom spray-wpm 400
  98   "Words per minute"
  99   :group 'spray
 100   :type 'integer)
 101
 102 (defcustom spray-height 400
 103   "Height of characters"
 104   :group 'spray
 105   :type 'integer)
 106
 107 (defcustom spray-margin-top 1
 108   "Character margin at top of buffer. Characters are as big as
 109   spray text characters."
 110   :group 'spray
 111   :type 'integer)
 112
 113 (defcustom spray-margin-left 1
 114   "Character margin at left of buffer. Characters are as big as
 115   spray text characters."
 116   :group 'spray
 117   :type 'integer)
 118
 119 (defcustom spray-ramp 2
 120   "Initial words before ramping up to full speed. Pauses for
 121 this multiple of wpm on the first word,
 122 decreasing by one for each subsequent word."
 123   :group 'spray
 124   :type 'integer)
 125
 126 (defcustom spray-unsupported-minor-modes
 127   '(buffer-face-mode smartparens-mode highlight-symbol-mode)
 128   "Minor modes to toggle off when in spray mode."
 129   :group 'spray
 130   :type '(list symbol))
 131
 132
 133 ;; * faces
 134
 135 (defface spray-base-face
 136   '((t (:inherit default)))
 137   "Face for non-accent characters."
 138   :group 'spray)
 139
 140 (defface spray-accent-face
 141   '((t (:foreground "red" :inherit spray-base-face)))
 142   "Face for accent character."
 143   :group 'spray)
 144
 145
 146 ;; keymap
 147
 148 (defvar spray-mode-map
 149   (let ((km (make-sparse-keymap)))
 150     (define-key km (kbd "SPC") 'spray-start/stop)
 151     (define-key km (kbd "h") 'spray-backward-word)
 152     (define-key km (kbd "l") 'spray-forward-word)
 153     (define-key km (kbd "<left>") 'spray-backward-word)
 154     (define-key km (kbd "<right>") 'spray-forward-word)
 155     (define-key km (kbd "f") 'spray-faster)
 156     (define-key km (kbd "s") 'spray-slower)
 157     (define-key km (kbd "q") 'spray-quit)
 158     (define-key km (kbd "<return>") 'spray-quit)
 159     (define-key km [remap forward-char] 'spray-forward-word)
 160     (define-key km [remap backward-char] 'spray-backward-word)
 161     (define-key km [remap forward-word] 'spray-forward-word)
 162     (define-key km [remap backward-word] 'spray-backward-word)
 163     (define-key km [remap keyboard-quit] 'spray-quit)
 164     km)
 165   "keymap for spray-mode buffers")
 166
 167
 168 ;; * internal vars
 169
 170 (defvar spray--margin-string "")
 171 (defvar spray--base-overlay nil)
 172 (defvar spray--accent-overlay nil)
 173 (defvar spray--running nil)
 174 (defvar spray--first-words 0)
 175 (defvar spray--initial-delay 0)
 176 (defvar spray--delay 0)
 177 (defvar spray--saved-cursor-type nil)
 178 (defvar spray--saved-restriction nil)
 179 (defvar spray--saved-minor-modes nil)
 180
 181 ;; * utility functions
 182
 183 (defun spray-set-margins ()
 184   "Setup spray--margin-string"
 185   (setq spray--margin-string
 186         (concat (make-string spray-margin-top 10) ;; 10 = ascii newline
 187                 (make-string spray-margin-left 32)))) ;; 32 = ascii space
 188
 189 ;; * the mode
 190
 191 ;;;###autoload
 192 (define-minor-mode spray-mode
 193   "spray mode"
 194   :init nil
 195   :keymap spray-mode-map
 196   (cond (spray-mode
 197          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 198                spray--accent-overlay (make-overlay 0 0)
 199                spray--saved-cursor-type cursor-type
 200                spray--saved-restriction (and (buffer-narrowed-p)
 201                                              (cons (point-min) (point-max))))
 202          (dolist (mode spray-unsupported-minor-modes)
 203            (when (and (boundp mode) (eval mode))
 204              (funcall mode -1)
 205              (push mode spray--saved-minor-modes)))
 206          (setq cursor-type nil)
 207          (let ((buffer-face-mode-face `(:height ,spray-height)))
 208            (buffer-face-mode 1))
 209          (overlay-put spray--base-overlay 'priority 100)
 210          (overlay-put spray--base-overlay 'face 'spray-base-face)
 211          (overlay-put spray--accent-overlay 'priority 101)
 212          (overlay-put spray--accent-overlay 'face 'spray-accent-face)
 213          (spray-start))
 214         (t
 215          (spray-stop)
 216          (delete-overlay spray--accent-overlay)
 217          (delete-overlay spray--base-overlay)
 218          (buffer-face-mode -1)
 219          (if spray--saved-restriction
 220              (narrow-to-region (car spray--saved-restriction)
 221                                (cdr spray--saved-restriction))
 222            (widen))
 223          (setq cursor-type spray--saved-cursor-type)
 224          (dolist (mode spray--saved-minor-modes)
 225            (funcall mode 1))
 226          (setq spray--saved-minor-modes nil))))
 227
 228 (defun spray-quit ()
 229   "Exit spray mode."
 230   (interactive)
 231   (spray-mode -1))
 232
 233 (defun spray--word-at-point ()
 234   (skip-chars-backward "^\s\t\n—")
 235   (let* ((beg (point))
 236          (len (+ (skip-chars-forward "^\s\t\n—") (skip-chars-forward "—")))
 237          (end (point))
 238          (accent (+ beg (cl-case len
 239                        ((1) 1)
 240                        ((2 3 4 5) 2)
 241                        ((6 7 8 9) 3)
 242                        ((10 11 12 13) 4)
 243                        (t 5)))))
 244     ;; this fairly obfuscated, using magic numbers to store state
 245     ;; it would be nice to sometime patch this so it is more readable.
 246     ;; for greater than 9 length, we display for twice as long
 247     ;; for some punctuation, we display a blank
 248     (setq spray--delay (+ (if (> len 9) 1 0)
 249                           (if (looking-at "\n[\s\t\n]") 3 0)
 250                           (cl-case (char-before)
 251                             ((?. ?! ?\? ?\;) 3)
 252                             ((?, ?: ?—) 1)
 253                             (t 0))))
 254     (move-overlay spray--accent-overlay (1- accent) accent)
 255     (move-overlay spray--base-overlay beg end)
 256     (spray-set-margins)
 257     (overlay-put spray--base-overlay 'before-string
 258                  (concat spray--margin-string
 259                          (make-string (- 5 (- accent beg)) ?\s)))
 260     (narrow-to-region beg end)))
 261
 262 (defun spray--update ()
 263   (cond ((not (zerop spray--initial-delay))
 264          (setq spray--initial-delay (1- spray--initial-delay)))
 265         ((not (zerop spray--delay))
 266          (setq spray--delay (1- spray--delay))
 267          (when (= spray--delay 2)
 268            (narrow-to-region (point) (point))))
 269         (t
 270          (widen)
 271          (if (eobp)
 272              (spray-mode -1)
 273            (when (not (zerop spray--first-words))
 274              (setq spray--initial-delay spray--first-words)
 275              (setq spray--first-words (1- spray--first-words)))
 276            (skip-chars-forward "\s\t\n—")
 277            (spray--word-at-point)))))
 278
 279 ;; * interactive commands
 280
 281 (defun spray-start/stop ()
 282   "Toggle pause/unpause spray."
 283   (interactive)
 284   (or (spray-stop) (spray-start)))
 285
 286 (defun spray-stop ()
 287   "Pause spray.
 288 Returns t if spray was unpaused."
 289   (interactive)
 290   (prog1 spray--running
 291     (when spray--running
 292       (cancel-timer spray--running)
 293       (setq spray--running nil))))
 294
 295 (defun spray-start ()
 296   "Start / resume spray."
 297   (interactive)
 298   (setq spray--first-words spray-ramp)
 299   (setq spray--running
 300         (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 301
 302 (defun spray-forward-word ()
 303   (interactive)
 304   (spray-stop)
 305   (widen)
 306   (skip-chars-forward "\s\t\n—")
 307   (spray--word-at-point))
 308
 309 (defun spray-backward-word ()
 310   (interactive)
 311   (spray-stop)
 312   (widen)
 313   (skip-chars-backward "^\s\t\n—")
 314   (skip-chars-backward "\s\t\n—")
 315   (spray--word-at-point))
 316
 317 (defun spray-faster ()
 318   "Increases speed.
 319
 320 Increases the wpm (words per minute) parameter. See the variable
 321 `spray-wpm'."
 322   (interactive)
 323   (spray-inc-wpm 20))
 324
 325 (defun spray-slower ()
 326   "Decreases speed.
 327
 328 Decreases the wpm (words per minute) parameter. See the variable
 329 `spray-wpm'."
 330   (interactive)
 331   (spray-inc-wpm -20))
 332
 333 (defun spray-inc-wpm (delta)
 334   (let ((was-running spray--running))
 335     (spray-stop)
 336     (when (< 10 (+ spray-wpm delta))
 337       (setq spray-wpm (+ spray-wpm delta)))
 338     (and was-running (spray-backward-word))
 339     (message "spray wpm: %d" spray-wpm)
 340     (when was-running
 341       (spray-start))))
 342
 343 ;; * provide
 344
 345 (provide 'spray)
 346
 347 ;;; spray.el ends here