iankelling.org Git - spray/blob - spray.el

   1 ;;; spray.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 zk_phi
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation; either version 2 of the License, or
   8 ;; (at your option) any later version.
   9 ;;
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 ;; GNU General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program; if not, write to the Free Software
  17 ;; Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;; Author: zk_phi
  20 ;; URL: http://hins11.yu-yake.com/
  21 ;; Author: Ian Kelling <ian@iankelling.org>
  22 ;; Version: 0.0.2
  23
  24 ;;; Commentary:
  25
  26 ;; Put this script into a "load-path"ed directory, and load it in your
  27 ;; init file.
  28 ;;
  29 ;;   (require 'spray)
  30 ;;
  31 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  32 ;; also be useful.
  33 ;;
  34 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  35 ;;
  36 ;; For more informations, see Readme.org.
  37
  38 ;;; Change Log:
  39 ;; 0.0.0 test release
  40 ;; 0.0.1 add spray-set-margins
  41 ;; 0.0.2 margin options, speed control, better quit
  42
  43 ;;; Code:
  44
  45 (require 'face-remap)
  46
  47 ;; * customizable vars
  48
  49 (defvar spray-wpm 400 "words/min")
  50 (defvar spray-height 400 "height of characters")
  51 (defvar spray-margin-top 1 "character margin at top of buffer. Characters are as big as spray text characters.")
  52 (defvar spray-margin-left 0 "character margin at left of buffer. Characters are as big as spray text characters.")
  53
  54 (defvar spray-mode-map
  55   (let ((km (make-sparse-keymap)))
  56     (define-key km (kbd "SPC") 'spray-start/stop)
  57     (define-key km (kbd "h") 'spray-backward-word)
  58     (define-key km (kbd "l") 'spray-forward-word)
  59     (define-key km (kbd "<left>") 'spray-backward-word)
  60     (define-key km (kbd "<right>") 'spray-forward-word)
  61     (define-key km (kbd "f") 'spray-faster)
  62     (define-key km (kbd "q") 'spray-quit)
  63     (define-key km (kbd "<return>") 'spray-quit)
  64     km)
  65   "keymap for spray-mode buffers")
  66
  67 ;; * faces
  68
  69 (make-face 'spray-base-face)
  70 (set-face-attribute 'spray-base-face nil
  71                     :background (face-background 'default)
  72                     :foreground (face-foreground 'default)
  73                     :slant 'normal)
  74
  75 (make-face 'spray-accent-face)
  76 (set-face-attribute 'spray-accent-face nil
  77                     :foreground "red"
  78                     :overline (face-foreground 'default)
  79                     :underline (face-foreground 'default)
  80                     :slant 'normal)
  81
  82 ;; * internal vars
  83
  84 (defvar spray--margin-string ""
  85   "Currently not used.")
  86 (defvar spray--base-overlay nil)
  87 (defvar spray--orp-overlay nil)
  88 (defvar spray--running nil)
  89 (defvar spray--delay 0)
  90 (defvar spray--saved-cursor-type nil)
  91 (defvar spray--saved-buffer-face nil)
  92 (defvar spray--saved-restriction nil)
  93
  94 ;; * utility functions
  95
  96 (defun spray-set-margins ()
  97   "Setup spray--margin-string"
  98   (setq spray--margin-string
  99         (concat (make-string spray-margin-top 10) ;; 10 = ascii newline
 100                 (make-string spray-margin-left 32)))) ;; 32 = ascii space
 101
 102 ;; * the mode
 103
 104 ;;;###autoload
 105 (define-minor-mode spray-mode
 106   "spray mode"
 107   :init nil
 108   :keymap spray-mode-map
 109   (cond (spray-mode
 110          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 111                spray--orp-overlay (make-overlay 0 0)
 112                spray--saved-cursor-type cursor-type
 113                spray--saved-restriction (and (buffer-narrowed-p)
 114                                              (cons (point-min) (point-max)))
 115                spray--saved-buffer-face (and (boundp 'buffer-face-mode)
 116                                              buffer-face-mode
 117                                              buffer-face-mode-face))
 118          (setq cursor-type nil)
 119          (let ((buffer-face-mode-face `(:height ,spray-height)))
 120            (buffer-face-mode 1))
 121          (overlay-put spray--base-overlay 'priority 100)
 122          (overlay-put spray--base-overlay 'face 'spray-base-face)
 123          (overlay-put spray--orp-overlay 'priority 101)
 124          (overlay-put spray--orp-overlay 'face 'spray-accent-face)
 125          (spray-start))
 126         (t
 127          (setq cursor-type spray--saved-cursor-type)
 128          (if spray--saved-restriction
 129              (narrow-to-region (car spray--saved-restriction)
 130                                (cdr spray--saved-restriction))
 131            (widen))
 132          (buffer-face-mode -1)
 133          (if spray--saved-buffer-face
 134              (let ((buffer-face-mode-face spray--saved-buffer-face))
 135                (buffer-face-mode 1)))
 136          (delete-overlay spray--base-overlay)
 137          (delete-overlay spray--orp-overlay)
 138          (spray-stop))))
 139
 140 (defun spray-quit ()
 141   "Exit spray mode."
 142   (interactive)
 143   (spray-mode -1))
 144
 145 (defun spray--word-at-point ()
 146   (skip-chars-backward "^\s\t\n")
 147   (let* ((beg (point))
 148          (len (skip-chars-forward "^\s\t\n"))
 149          (end (point))
 150          (orp (+ beg (cl-case len
 151                        ((1) 1)
 152                        ((2 3 4 5) 2)
 153                        ((6 7 8 9) 3)
 154                        ((10 11 12 13) 4)
 155                        (t 5)))))
 156     (setq spray--delay (+ (if (> len 9) 1 0)
 157                           (if (looking-at "\n[\s\t\n]") 3 0)
 158                           (cl-case (char-before)
 159                             ((?. ?! ?\? ?\;) 3)
 160                             ((?, ?:) 1)
 161                             (t 0))))
 162     (move-overlay spray--orp-overlay (1- orp) orp)
 163     (move-overlay spray--base-overlay beg end)
 164     (spray-set-margins)
 165     (overlay-put spray--base-overlay 'before-string
 166                  (concat spray--margin-string
 167                          (make-string (- 5 (- orp beg)) ?\s)))
 168     (narrow-to-region beg end)))
 169
 170 (defun spray--update ()
 171   (cond ((not (zerop spray--delay))
 172          (setq spray--delay (1- spray--delay))
 173          (when (= spray--delay 2)
 174            (narrow-to-region (point) (point))))
 175         (t
 176          (widen)
 177          (if (eobp)
 178              (spray-mode -1)
 179            (skip-chars-forward "\s\t\n")
 180            (spray--word-at-point)))))
 181
 182 ;; * interactive commands
 183
 184 (defun spray-start/stop ()
 185   "Toggle pause/unpause spray."
 186   (interactive)
 187   (or (spray-stop) (spray-start)))
 188
 189 (defun spray-stop ()
 190   "Pause spray.
 191 Returns t if spray was unpaused."
 192   (interactive)
 193   (prog1 spray--running
 194     (when spray--running
 195       (cancel-timer spray--running)
 196       (setq spray--running nil))))
 197
 198 (defun spray-start ()
 199   "Start / resume spray."
 200   (interactive)
 201   (setq spray--running
 202         (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 203
 204
 205 (defun spray-forward-word ()
 206   (interactive)
 207   (spray-stop)
 208   (widen)
 209   (skip-chars-forward "\s\t\n")
 210   (spray--word-at-point))
 211
 212 (defun spray-backward-word ()
 213   (interactive)
 214   (spray-stop)
 215   (widen)
 216   (skip-chars-backward "^\s\t\n")
 217   (skip-chars-backward "\s\t\n")
 218   (spray--word-at-point))
 219
 220 (defun spray-faster ()
 221   "Increases speed.
 222
 223 Increases the wpm (words per minute) parameter. See the variable
 224 `spray-wmp'."
 225   (interactive)
 226   (spray-inc-wpm 20))
 227
 228 (defun spray-slower ()
 229   "Decreases speed.
 230
 231 Decreases the wpm (words per minute) parameter. See the variable
 232 `spray-wmp'."
 233   (interactive)
 234   (spray-inc-wpm -20))
 235
 236 (defun spray-inc-wpm (delta)
 237   (let ((was-running spray--running))
 238     (spray-stop)
 239     (when (< 10 (+ spray-wpm delta))
 240       (setq spray-wpm (+ spray-wpm delta)))
 241     (and was-running (spray-backward-word))
 242     (message "spray wpm: %d" spray-wpm)
 243     (when was-running
 244       (spray-start))))
 245
 246 ;; * provide
 247
 248 (provide 'spray)
 249
 250 ;;; spray.el ends here