iankelling.org Git - spray/blob - spray.el

   1 ;;; spray.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 Ian Kelling <ian@iankelling.org>
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation, either version 3 of the License, or
   8 ;; (at your option) any later version.
   9
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;; GNU General Public License for more details.
  14
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;; Maintainer: Ian Kelling <ian@iankelling.org>
  19 ;; Author: Ian Kelling <ian@iankelling.org>
  20 ;; Author: zk_phi
  21 ;; Created: 18 Jun 2014
  22 ;; Version: 0.0.2
  23 ;; URL: https://github.com/ian-kelling/spray
  24 ;; Mailing list: https://lists.iankelling.org/listinfo/spray
  25 ;; Keywords: convenience
  26
  27 ;;; Commentary:
  28
  29 ;; For speed reading, or just more enjoyable reading. Narrows the buffer to show
  30 ;; one word at a time. Adjust speed / pause as needed.
  31 ;;
  32 ;; Download from Melpa or put this script into a "load-path"ed directory, and
  33 ;; load it in your init file:
  34
  35 ;;   (require 'spray)
  36
  37 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  38 ;; also be useful.
  39
  40 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  41
  42 ;; In spray-mode buffers, following commands are available.
  43
  44 ;; - =spray-start/stop= (SPC) ::
  45 ;; pause or resume spraying
  46
  47 ;; - =spray-backward-word= (h, <left>) ::
  48 ;; pause and back to the last word
  49
  50 ;; - =spray-forward-word= (l, <right>) ::
  51 ;; inverse of =spray-backward-word=
  52
  53 ;; - =spray-faster= (f) ::
  54 ;; increases speed
  55
  56 ;; - =spray-slower= (s) ::
  57 ;; decreases speed
  58
  59 ;; - =spray-quit= (q, <return>) ::
  60 ;; quit =spray-mode=
  61
  62 ;; You may customize spray by modifying following items:
  63
  64 ;; - [Variable] spray-wpm
  65 ;; - [Variable] spray-height
  66 ;; - [Variable] spray-margin-top
  67 ;; - [Variable] spray-margin-left
  68 ;; - [Variable] spray-ramp
  69 ;; - [Keymap] spray-mode-map
  70 ;; - [Face] spray-base-face
  71 ;; - [Face] spray-accent-face
  72
  73 ;; Readme.org from the package repository has some additional information:
  74 ;; A gif screencast.
  75 ;; Algorithm specification.
  76 ;; Comparison with similar projects.
  77
  78 ;;; Known bugs:
  79
  80 ;; repeated words are indistinguishable, for example
  81 ;; "going, going, gone" reads like going, gone, with a slight delay.
  82 ;;
  83 ;; sentences (like this) should trigger a pause for ( and )
  84
  85 ;;; Change Log:
  86
  87 ;; 0.0.0 test release
  88 ;; 0.0.1 add spray-set-margins
  89 ;; 0.0.2 margin options, speed control, better quit
  90
  91 ;;; Code:
  92
  93 (require 'face-remap)
  94
  95 ;; * customizable vars
  96
  97 (defcustom spray-wpm 400
  98   "Words per minute"
  99   :group 'spray
 100   :type 'integer)
 101
 102 (defcustom spray-height 400
 103   "Height of characters"
 104   :group 'spray
 105   :type 'integer)
 106
 107 (defcustom spray-margin-top 1
 108   "Character margin at top of buffer. Characters are as big as
 109   spray text characters."
 110   :group 'spray
 111   :type 'integer)
 112
 113 (defcustom spray-margin-left 1
 114   "Character margin at left of buffer. Characters are as big as
 115   spray text characters."
 116   :group 'spray
 117   :type 'integer)
 118
 119 (defcustom spray-ramp 2
 120   "Initial words before ramping up to full speed. Pauses for
 121 this multiple of wpm on the first word,
 122 decreasing by one for each subsequent word."
 123   :group 'spray
 124   :type 'integer)
 125
 126 (defcustom spray-unsupported-minor-modes
 127   '(buffer-face-mode smartparens-mode highlight-symbol-mode
 128                      column-number-mode)
 129   "Minor modes to toggle off when in spray mode."
 130   :group 'spray
 131   :type '(list symbol))
 132
 133
 134 ;; * faces
 135
 136 (defface spray-base-face
 137   '((t (:inherit default)))
 138   "Face for non-accent characters."
 139   :group 'spray)
 140
 141 (defface spray-accent-face
 142   '((t (:foreground "red" :inherit spray-base-face)))
 143   "Face for accent character."
 144   :group 'spray)
 145
 146
 147 ;; keymap
 148
 149 (defvar spray-mode-map
 150   (let ((km (make-sparse-keymap)))
 151     (define-key km (kbd "SPC") 'spray-start/stop)
 152     (define-key km (kbd "h") 'spray-backward-word)
 153     (define-key km (kbd "l") 'spray-forward-word)
 154     (define-key km (kbd "<left>") 'spray-backward-word)
 155     (define-key km (kbd "<right>") 'spray-forward-word)
 156     (define-key km (kbd "f") 'spray-faster)
 157     (define-key km (kbd "s") 'spray-slower)
 158     (define-key km (kbd "q") 'spray-quit)
 159     (define-key km (kbd "<return>") 'spray-quit)
 160     (define-key km [remap forward-char] 'spray-forward-word)
 161     (define-key km [remap backward-char] 'spray-backward-word)
 162     (define-key km [remap forward-word] 'spray-forward-word)
 163     (define-key km [remap backward-word] 'spray-backward-word)
 164     (define-key km [remap keyboard-quit] 'spray-quit)
 165     km)
 166   "keymap for spray-mode buffers")
 167
 168
 169 ;; * internal vars
 170
 171 (defvar spray--margin-string "")
 172 (defvar spray--base-overlay nil)
 173 (defvar spray--accent-overlay nil)
 174 (defvar spray--running nil)
 175 (defvar spray--first-words 0)
 176 (defvar spray--initial-delay 0)
 177 (defvar spray--delay 0)
 178 (defvar spray--saved-cursor-type nil)
 179 (defvar spray--saved-restriction nil)
 180 (defvar spray--saved-minor-modes nil)
 181
 182 ;; * utility functions
 183
 184 (defun spray-set-margins ()
 185   "Setup spray--margin-string"
 186   (setq spray--margin-string
 187         (concat (make-string spray-margin-top 10) ;; 10 = ascii newline
 188                 (make-string spray-margin-left 32)))) ;; 32 = ascii space
 189
 190 ;; * the mode
 191
 192 ;;;###autoload
 193 (define-minor-mode spray-mode
 194   "spray mode"
 195   :init nil
 196   :keymap spray-mode-map
 197   (cond (spray-mode
 198          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 199                spray--accent-overlay (make-overlay 0 0)
 200                spray--saved-cursor-type cursor-type
 201                spray--saved-restriction (and (buffer-narrowed-p)
 202                                              (cons (point-min) (point-max))))
 203          (dolist (mode spray-unsupported-minor-modes)
 204            (when (and (boundp mode) (eval mode))
 205              (funcall mode -1)
 206              (push mode spray--saved-minor-modes)))
 207          (setq cursor-type nil)
 208          (let ((buffer-face-mode-face `(:height ,spray-height)))
 209            (buffer-face-mode 1))
 210          (overlay-put spray--base-overlay 'priority 100)
 211          (overlay-put spray--base-overlay 'face 'spray-base-face)
 212          (overlay-put spray--accent-overlay 'priority 101)
 213          (overlay-put spray--accent-overlay 'face 'spray-accent-face)
 214          (spray-start))
 215         (t
 216          (spray-stop)
 217          (delete-overlay spray--accent-overlay)
 218          (delete-overlay spray--base-overlay)
 219          (buffer-face-mode -1)
 220          (if spray--saved-restriction
 221              (narrow-to-region (car spray--saved-restriction)
 222                                (cdr spray--saved-restriction))
 223            (widen))
 224          (setq cursor-type spray--saved-cursor-type)
 225          (dolist (mode spray--saved-minor-modes)
 226            (funcall mode 1))
 227          (setq spray--saved-minor-modes nil))))
 228
 229 (defun spray-quit ()
 230   "Exit spray mode."
 231   (interactive)
 232   (spray-mode -1))
 233
 234 (defun spray--word-at-point ()
 235   (skip-chars-backward "^\s\t\n—")
 236   (let* ((beg (point))
 237          (len (+ (skip-chars-forward "^\s\t\n—") (skip-chars-forward "—")))
 238          (end (point))
 239          (accent (+ beg (cl-case len
 240                        ((1) 1)
 241                        ((2 3 4 5) 2)
 242                        ((6 7 8 9) 3)
 243                        ((10 11 12 13) 4)
 244                        (t 5)))))
 245     ;; this fairly obfuscated, using magic numbers to store state
 246     ;; it would be nice to sometime patch this so it is more readable.
 247     ;; for greater than 9 length, we display for twice as long
 248     ;; for some punctuation, we display a blank
 249     (setq spray--delay (+ (if (> len 9) 1 0)
 250                           (if (looking-at "\n[\s\t\n]") 3 0)
 251                           (cl-case (char-before)
 252                             ((?. ?! ?\? ?\;) 3)
 253                             ((?, ?: ?—) 1)
 254                             (t 0))))
 255     (move-overlay spray--accent-overlay (1- accent) accent)
 256     (move-overlay spray--base-overlay beg end)
 257     (spray-set-margins)
 258     (overlay-put spray--base-overlay 'before-string
 259                  (concat spray--margin-string
 260                          (make-string (- 5 (- accent beg)) ?\s)))
 261     (narrow-to-region beg end)))
 262
 263 (defun spray--update ()
 264   (cond ((not (zerop spray--initial-delay))
 265          (setq spray--initial-delay (1- spray--initial-delay)))
 266         ((not (zerop spray--delay))
 267          (setq spray--delay (1- spray--delay))
 268          (when (= spray--delay 2)
 269            (narrow-to-region (point) (point))))
 270         (t
 271          (widen)
 272          (if (eobp)
 273              (spray-quit)
 274            (when (not (zerop spray--first-words))
 275              (setq spray--initial-delay spray--first-words)
 276              (setq spray--first-words (1- spray--first-words)))
 277            (skip-chars-forward "\s\t\n—")
 278            (spray--word-at-point)))))
 279
 280 ;; * interactive commands
 281
 282 (defun spray-start/stop ()
 283   "Toggle pause/unpause spray."
 284   (interactive)
 285   (or (spray-stop) (spray-start)))
 286
 287 (defun spray-stop ()
 288   "Pause spray.
 289 Returns t if spray was unpaused."
 290   (interactive)
 291   (prog1 spray--running
 292     (when spray--running
 293       (cancel-timer spray--running)
 294       (setq spray--running nil))))
 295
 296 (defun spray-start ()
 297   "Start / resume spray."
 298   (interactive)
 299   (setq spray--first-words spray-ramp)
 300   (setq spray--running
 301         (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 302
 303 (defun spray-forward-word ()
 304   (interactive)
 305   (spray-stop)
 306   (widen)
 307   (skip-chars-forward "\s\t\n—")
 308   (spray--word-at-point))
 309
 310 (defun spray-backward-word ()
 311   (interactive)
 312   (spray-stop)
 313   (widen)
 314   (skip-chars-backward "^\s\t\n—")
 315   (skip-chars-backward "\s\t\n—")
 316   (spray--word-at-point))
 317
 318 (defun spray-faster ()
 319   "Increases speed.
 320
 321 Increases the wpm (words per minute) parameter. See the variable
 322 `spray-wpm'."
 323   (interactive)
 324   (spray-inc-wpm 20))
 325
 326 (defun spray-slower ()
 327   "Decreases speed.
 328
 329 Decreases the wpm (words per minute) parameter. See the variable
 330 `spray-wpm'."
 331   (interactive)
 332   (spray-inc-wpm -20))
 333
 334 (defun spray-inc-wpm (delta)
 335   (let ((was-running spray--running))
 336     (spray-stop)
 337     (when (< 10 (+ spray-wpm delta))
 338       (setq spray-wpm (+ spray-wpm delta)))
 339     (and was-running (spray-backward-word))
 340     (message "spray wpm: %d" spray-wpm)
 341     (when was-running
 342       (spray-start))))
 343
 344 ;; * provide
 345
 346 (provide 'spray)
 347
 348 ;;; spray.el ends here