iankelling.org Git - spray/blob - spray.el

   1 ;;; spray.el --- a speed reading mode
   2
   3 ;; Copyright (C) 2014 zk_phi
   4
   5 ;; This program is free software; you can redistribute it and/or modify
   6 ;; it under the terms of the GNU General Public License as published by
   7 ;; the Free Software Foundation; either version 2 of the License, or
   8 ;; (at your option) any later version.
   9 ;;
  10 ;; This program is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 ;; GNU General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with this program; if not, write to the Free Software
  17 ;; Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;; Author: zk_phi
  20 ;; URL: http://hins11.yu-yake.com/
  21 ;; Author: Ian Kelling <ian@iankelling.org>
  22 ;; Version: 0.0.2
  23
  24 ;;; Commentary:
  25
  26 ;; Put this script into a "load-path"ed directory, and load it in your
  27 ;; init file.
  28 ;;
  29 ;;   (require 'spray)
  30 ;;
  31 ;; Then you may run spray with "M-x spray-mode". Binding some keys may
  32 ;; also be useful.
  33 ;;
  34 ;;   (global-set-key (kbd "<f6>") 'spray-mode)
  35 ;;
  36 ;; For more informations, see Readme.org.
  37
  38 ;;; Change Log:
  39 ;; 0.0.0 test release
  40 ;; 0.0.1 add spray-set-margins
  41 ;; 0.0.2 margin options, speed control, better quit
  42
  43 ;;; Code:
  44
  45 (require 'face-remap)
  46
  47 ;; * customizable vars
  48
  49 (defvar spray-wpm 400 "words/min")
  50 (defvar spray-height 400 "height of characters")
  51 (defvar spray-margin-top 1 "character margin at top of buffer. Characters are as big as spray text characters.")
  52 (defvar spray-margin-left 0 "character margin at left of buffer. Characters are as big as spray text characters.")
  53
  54 (defvar spray-mode-map
  55   (let ((km (make-sparse-keymap)))
  56     (define-key km (kbd "SPC") 'spray-start/stop)
  57     (define-key km (kbd "h") 'spray-backward-word)
  58     (define-key km (kbd "l") 'spray-forward-word)
  59     (define-key km (kbd "<left>") 'spray-backward-word)
  60     (define-key km (kbd "<right>") 'spray-forward-word)
  61     (define-key km (kbd "f") 'spray-faster)
  62     (define-key km (kbd "s") 'spray-slower)
  63     (define-key km (kbd "q") 'spray-quit)
  64     (define-key km (kbd "<return>") 'spray-quit)
  65     km)
  66   "keymap for spray-mode buffers")
  67
  68 ;; * faces
  69
  70 (make-face 'spray-base-face)
  71 (set-face-attribute 'spray-base-face nil
  72                     :background (face-background 'default)
  73                     :foreground (face-foreground 'default)
  74                     :slant 'normal)
  75
  76 (make-face 'spray-accent-face)
  77 (set-face-attribute 'spray-accent-face nil
  78                     :foreground "red"
  79                     :overline (face-foreground 'default)
  80                     :underline (face-foreground 'default)
  81                     :slant 'normal)
  82
  83 ;; * internal vars
  84
  85 (defvar spray--margin-string ""
  86   "Currently not used.")
  87 (defvar spray--base-overlay nil)
  88 (defvar spray--accent-overlay nil)
  89 (defvar spray--running nil)
  90 (defvar spray--delay 0)
  91 (defvar spray--saved-cursor-type nil)
  92 (defvar spray--saved-buffer-face nil)
  93 (defvar spray--saved-restriction nil)
  94 (defvar spray--saved-smartparens-enabled nil)
  95
  96 ;; * utility functions
  97
  98 (defun spray-set-margins ()
  99   "Setup spray--margin-string"
 100   (setq spray--margin-string
 101         (concat (make-string spray-margin-top 10) ;; 10 = ascii newline
 102                 (make-string spray-margin-left 32)))) ;; 32 = ascii space
 103
 104 ;; * the mode
 105
 106 ;;;###autoload
 107 (define-minor-mode spray-mode
 108   "spray mode"
 109   :init nil
 110   :keymap spray-mode-map
 111   (cond (spray-mode
 112          (setq spray--base-overlay (make-overlay (point-min) (point-max))
 113                spray--accent-overlay (make-overlay 0 0)
 114                spray--saved-cursor-type cursor-type
 115                spray--saved-restriction (and (buffer-narrowed-p)
 116                                              (cons (point-min) (point-max)))
 117                spray--saved-buffer-face (and (boundp 'buffer-face-mode)
 118                                              buffer-face-mode
 119                                              buffer-face-mode-face)
 120                spray--saved-smartparens-enabled (and (boundp 'smartparens-mode)
 121                                                      smartparens-mode)
 122                spray--saved-highlight-symbol-enabled (and (boundp 'highlight-symbol-mode)
 123                                                      highlight-symbol-mode))
 124          ;; smartparens wrapping of all letter binds can cause problems.
 125          ;; for example, it can cause auto-complete to activate
 126          (and spray--saved-smartparens-enabled (smartparens-mode -1))
 127          (and spray--saved-highlight-symbol-enabled (highlight-symbol-mode -1))
 128          (setq cursor-type nil)
 129          (let ((buffer-face-mode-face `(:height ,spray-height)))
 130            (buffer-face-mode 1))
 131          (overlay-put spray--base-overlay 'priority 100)
 132          (overlay-put spray--base-overlay 'face 'spray-base-face)
 133          (overlay-put spray--accent-overlay 'priority 101)
 134          (overlay-put spray--accent-overlay 'face 'spray-accent-face)
 135          (spray-start))
 136         (t
 137          (and spray--saved-smartparens-enabled (smartparens-mode 1))
 138          (and spray--saved-highlight-symbol-enabled (highlight-symbol-mode 1))
 139          (setq cursor-type spray--saved-cursor-type)
 140          (if spray--saved-restriction
 141              (narrow-to-region (car spray--saved-restriction)
 142                                (cdr spray--saved-restriction))
 143            (widen))
 144          (buffer-face-mode -1)
 145          (if spray--saved-buffer-face
 146              (let ((buffer-face-mode-face spray--saved-buffer-face))
 147                (buffer-face-mode 1)))
 148          (delete-overlay spray--base-overlay)
 149          (delete-overlay spray--accent-overlay)
 150          (spray-stop))))
 151
 152 (defun spray-quit ()
 153   "Exit spray mode."
 154   (interactive)
 155   (spray-mode -1))
 156
 157 (defun spray--word-at-point ()
 158   (skip-chars-backward "^\s\t\n")
 159   (let* ((beg (point))
 160          (len (skip-chars-forward "^\s\t\n"))
 161          (end (point))
 162          (accent (+ beg (cl-case len
 163                        ((1) 1)
 164                        ((2 3 4 5) 2)
 165                        ((6 7 8 9) 3)
 166                        ((10 11 12 13) 4)
 167                        (t 5)))))
 168     (setq spray--delay (+ (if (> len 9) 1 0)
 169                           (if (looking-at "\n[\s\t\n]") 3 0)
 170                           (cl-case (char-before)
 171                             ((?. ?! ?\? ?\;) 3)
 172                             ((?, ?:) 1)
 173                             (t 0))))
 174     (move-overlay spray--accent-overlay (1- accent) accent)
 175     (move-overlay spray--base-overlay beg end)
 176     (spray-set-margins)
 177     (overlay-put spray--base-overlay 'before-string
 178                  (concat spray--margin-string
 179                          (make-string (- 5 (- accent beg)) ?\s)))
 180     (narrow-to-region beg end)))
 181
 182 (defun spray--update ()
 183   (cond ((not (zerop spray--delay))
 184          (setq spray--delay (1- spray--delay))
 185          (when (= spray--delay 2)
 186            (narrow-to-region (point) (point))))
 187         (t
 188          (widen)
 189          (if (eobp)
 190              (spray-mode -1)
 191            (skip-chars-forward "\s\t\n")
 192            (spray--word-at-point)))))
 193
 194 ;; * interactive commands
 195
 196 (defun spray-start/stop ()
 197   "Toggle pause/unpause spray."
 198   (interactive)
 199   (or (spray-stop) (spray-start)))
 200
 201 (defun spray-stop ()
 202   "Pause spray.
 203 Returns t if spray was unpaused."
 204   (interactive)
 205   (prog1 spray--running
 206     (when spray--running
 207       (cancel-timer spray--running)
 208       (setq spray--running nil))))
 209
 210 (defun spray-start ()
 211   "Start / resume spray."
 212   (interactive)
 213   (setq spray--running
 214         (run-with-timer 0 (/ 60.0 spray-wpm) 'spray--update)))
 215
 216
 217 (defun spray-forward-word ()
 218   (interactive)
 219   (spray-stop)
 220   (widen)
 221   (skip-chars-forward "\s\t\n")
 222   (spray--word-at-point))
 223
 224 (defun spray-backward-word ()
 225   (interactive)
 226   (spray-stop)
 227   (widen)
 228   (skip-chars-backward "^\s\t\n")
 229   (skip-chars-backward "\s\t\n")
 230   (spray--word-at-point))
 231
 232 (defun spray-faster ()
 233   "Increases speed.
 234
 235 Increases the wpm (words per minute) parameter. See the variable
 236 `spray-wmp'."
 237   (interactive)
 238   (spray-inc-wpm 20))
 239
 240 (defun spray-slower ()
 241   "Decreases speed.
 242
 243 Decreases the wpm (words per minute) parameter. See the variable
 244 `spray-wmp'."
 245   (interactive)
 246   (spray-inc-wpm -20))
 247
 248 (defun spray-inc-wpm (delta)
 249   (let ((was-running spray--running))
 250     (spray-stop)
 251     (when (< 10 (+ spray-wpm delta))
 252       (setq spray-wpm (+ spray-wpm delta)))
 253     (and was-running (spray-backward-word))
 254     (message "spray wpm: %d" spray-wpm)
 255     (when was-running
 256       (spray-start))))
 257
 258 ;; * provide
 259
 260 (provide 'spray)
 261
 262 ;;; spray.el ends here